【Excel VBA】CSVファイルを読み込んでシートにコピーする2つの方法を紹介

Sub データ読込_シートコピー()

Dim MyBookName As String
Dim MySheet As Worksheet
Dim CopyBookName As String
Dim FName As String
Dim CopySheetName As String

    '動作非表示
    Application.ScreenUpdating = False

    'このブック名保存
    MyBookName = Application.ThisWorkbook.Name
    
    '初期フォルダをブックと同じフォルダを指定
    ChDir ThisWorkbook.Path
    
    'ファイル指定のダイアログを開く
    FName = Application.GetOpenFilename(FileFilter:="CSVファイル(*.csv),*.csv", Title:="読込みたいCSVファイルを選択して下さい。")
    
    'キャンセルを押された場合、メッセージを表示して抜ける
    If FName = "False" Then
        MsgBox "ファイルが選択されていないため終了します。"
        End
    End If
    
    'ファイルを開き、ブック名とシート名を保存
    Workbooks.Open FName
    CopyBookName = ActiveWorkbook.Name
    CopySheetName = ActiveSheet.Name
    
    'ブック名を確認し、違う場合はメッセージを表示してファイルを閉じる
    If Not CopyBookName Like "CSV*" Then
        MsgBox "対象のcsvファイルではありません。"
        ActiveWorkbook.Close    'アクティブブックを閉じる
        End
    End If
    
    '既存のブックのCSVシートを削除
    Workbooks(MyBookName).Activate                  '既存ブックをアクティブ
    For Each MySheet In Worksheets                  '既存ブックのシートに対して繰り返す
        If MySheet.Name Like "CSV*" Then            'CSVの名前を含むシートを削除
            Application.DisplayAlerts = False       '警告非表示
            MySheet.Delete
        End If
    Next
    
    'CSVシートをコピーして名前を変更
    'データを読込むシートを初期化し、データをコピーする
    Workbooks(CopyBookName).Sheets(CopySheetName).Copy After:=Workbooks(MyBookName).Sheets("メイン")
    ActiveSheet.Name = "CSVデータ"
    
    'CSVファイルを閉じる
    Workbooks(CopyBookName).Close
    
    MsgBox ("データを読み込みました。")
    
End Sub

Sub データ読込_データコピー()

Dim MyBookName As String
Dim CopyBookName As String
Dim FName As String
Dim CopySheetName As String
Dim PastePnt As Range
Dim CopyAr As Range

    '動作非表示
    Application.ScreenUpdating = False

    'このブック名保存
    MyBookName = Application.ThisWorkbook.Name
    
    '初期フォルダをブックと同じフォルダを指定
    ChDir ThisWorkbook.Path
    
    'ファイル指定のダイアログを開く
    FName = Application.GetOpenFilename(FileFilter:="CSVファイル(*.csv),*.csv", Title:="読込みたいCSVファイルを選択して下さい。")
    
    'キャンセルを押された場合、メッセージを表示して抜ける
    If FName = "False" Then
        MsgBox "ファイルが選択されていないため終了します。"
        End
    End If
    
    'ファイルを開き、ブック名とシート名を保存
    Workbooks.Open FName
    CopyBookName = ActiveWorkbook.Name
    CopySheetName = ActiveSheet.Name
    
    'ブック名を確認し、違う場合はメッセージを表示してファイルを閉じる
    If Not CopyBookName Like "CSV*" Then
        MsgBox "対象のcsvファイルではありません。"
        ActiveWorkbook.Close    'アクティブブックを閉じる
        End
    End If
    
    'データを読込むシートを初期化し、データをコピーする
    Workbooks(MyBookName).Sheets("CSVデータ").UsedRange.ClearContents       'CSVデータシート初期化
    Set PastePnt = Workbooks(MyBookName).Sheets("CSVデータ").[A1]           '貼り付け先セット
    Set CopyAr = Workbooks(CopyBookName).Sheets(CopySheetName).UsedRange    'コピー元セット
    CopyAr.Copy PastePnt    'コピーして貼り付け
    ActiveWorkbook.Close    'アクティブブック（開いたブック）を閉じる
    
    'メインシート選択
    Workbooks(MyBookName).Sheets("メイン").Activate
    
    MsgBox ("データを読み込みました。")
    
End Sub